#include <Arduino.h>
#include <BleKeyboard.h>

#define PIN_BTN 4  // → GND
#define PIN_LED 16 // → LED
constexpr TickType_t REPEAT_RATE = pdMS_TO_TICKS(500); // 发送间隔

/*--------------------------------------------------*/
BleKeyboard bleKeyboard("21's Knob", "luowei", 88);

/*--------------------------------------------------*/
/* 中断服务程序 */
static TaskHandle_t hKeyTask = NULL;
static void IRAM_ATTR onBtnChange(void *)
{
  BaseType_t xHigherPriorityTaskWoken = pdFALSE;
  if (hKeyTask != NULL)
    vTaskNotifyGiveFromISR(hKeyTask, &xHigherPriorityTaskWoken); // 中断唤醒任务
  portYIELD_FROM_ISR(xHigherPriorityTaskWoken); // 效果：把“按键事件”的响应延迟缩到最短，避免 ISR 结束后还要等系统时钟滴答才轮到 keyTask 运行。
}

/*--------------------------------------------------*/
/* 负责真正干活的任务，优先级高于 loop() */
void keyTask(void *)
{
  for (;;)
  {
    /* 自己主动睡觉，等待中断唤醒 */
    ulTaskNotifyTake(pdTRUE, portMAX_DELAY);

    /* 抗尖刺：再读一次，确认仍是按下 */
    if (digitalRead(PIN_BTN) == LOW)
    {
      /* —— 第一次按下 —— */
      if (bleKeyboard.isConnected())
      {
        bleKeyboard.write(KEY_LEFT_CTRL);
        vTaskDelay(pdMS_TO_TICKS(30));
        bleKeyboard.print(" ");
      }
      digitalWrite(PIN_LED, HIGH);
      vTaskDelay(REPEAT_RATE);

      /* —— 连发循环 —— */
      while (digitalRead(PIN_BTN) == LOW)
      {
        if (bleKeyboard.isConnected())
        {
          bleKeyboard.write(KEY_LEFT_CTRL);
          vTaskDelay(pdMS_TO_TICKS(30));
          bleKeyboard.print(" ");
        }
        vTaskDelay(REPEAT_RATE);
      }

      /* 松手后关灯 */
      digitalWrite(PIN_LED, LOW);
    }
  }
}

/*--------------------------------------------------*/
void setup()
{
  Serial.begin(115200);

  pinMode(PIN_BTN, INPUT_PULLUP);
  pinMode(PIN_LED, OUTPUT);

  /* 1. 下落沿中断，唤醒 keyTask */
  attachInterruptArg(PIN_BTN, onBtnChange, nullptr, FALLING);

  /* 2. 创建高优先进程 */
  xTaskCreatePinnedToCore(
      keyTask,
      "keyTask",
      4096,
      nullptr,
      3, // 优先级高于 loop()
      &hKeyTask,
      1); // 跑在 Core 1，蓝牙跑在 Core 0，互不抢占

  bleKeyboard.begin();
}

/*--------------------------------------------------*/
void loop()
{
  /* 所有实时工作已放在 keyTask，loop() 空转即可 */
  vTaskDelay(portMAX_DELAY);
}

ulTaskNotifyTake设计对比任务一直检测按钮高低电平有什么优缺点？